Voetsjoeba signature...

[valpez1]

O.k i've been pulling my hair out for about 3 days now trying to figure out how Voetsjoeba created his signature. I realize it has something to do with the position of the mc, but i don't understand the rest. Any ideas?

[claudio]

Maybe check his tutorial? :beam:
http://www.kirupa.com/developer/mx/fadegrid.htm

[valpez1]

true, that is a very neat looking effect....but it isn't exactly what i was looking for, or maybe it is....and i just don't understand it. But search around for Voetsjoeba's signature movie clip. It 'shakes' somewhat when the mouse moves over.

[Seticus]

onClipEvent (load) {
dist = 2;
posxoriginal = _x;
posyoriginal = _y;
}
onClipEvent (enterFrame) {
i += random(4);
randomnum = Math.pow(-1, i)*Math.random()*dist;
_x = posxoriginal+randomnum;
_y = posyoriginal+randomnum;
_alpha = random(100);
}


given to a mc, should be the effect you are looking for :panda:

[valpez1]

exactly the look i'm going for thanks, but instead of the mc automatically movie on it's own, is their a way for the mouse to trigger the start of the movement....but without turning it into a button. I'm only able to make the effect work if it's a button...but i'm sure there's a way to keep it as just a mc.

[claudio]

Sorry valpez, i hadnt realized voetsjoeba changed his footer :P

[valpez1]

don't worry about it :D

[Seticus]

I guess something like this:

dist = 2;
posxoriginal = nameofyourmc._x;
posyoriginal = nameofyourmc._y;
this.onEnterFrame = function() {
if (m == 1) {
i += random(4);
randomnum = Math.pow(-1, i)*Math.random()*dist;
nameofyourmc._x = posxoriginal+randomnum;
nameofyourmc._y = posyoriginal+randomnum;
nameofyourmc._alpha = random(100);
}
};
nameofyourmc.onRollOver = function() {
m = 1;
};
nameofyourmc.onRollOut = function() {
m = 0;
};

when the mc is called "nameofyourmc". These actions are given to the frame

[valpez1]

great, thanks so much Seticus. I just completely forgot about the .function ()

[Voetsjoeba]

Glad you like it :) I got tired of that other footer. In case you're still wondering even though Seticus gave a nice example, here's the exact code I used.



MovieClip.prototype.useHandCursor = false;
orX = elec._x;
orY = elec._y;
anim = null;
returnRan = function () {
if (Math.floor(Math.random()*2)) {
return -Math.random()*2;
} else {
return Math.random()*2;
}
};
animate = function () {
elec._alpha = Math.random()*100;
elec._x = orX+returnRan();
elec._y = orY+returnRan();
};
elec.onRollOver = function() {
anim = setInterval(animate, 20);
};
elec.onRollOut = function() {
clearInterval(anim);
this._alpha = 100;
this._x = orX;
this._y = orY;
};

[valpez1]

thanks a lot, now i don't know which one to use =) But thanks all the same guys.

[valpez1]

oh wait one quick question voets....i attached your code to my movieclip, but it still doesnt work....is there anything i'm doing wrong? I'm thinking i need to input my instance name somewhere in your code...but it never works anyway....very confused :-/

[Voetsjoeba]

I used two images - one with the electric image and one with the text. I placed them both in movieclips, and I gave the movieclip containing the electricity image the instance name 'elec'. You have to change that to the instance name of your own movieclip (or call your movieclip elec :D).

[valpez1]

that's what i assumed you did, gave it an instance name. But when i did just like you said, i even kept the instance name as 'elec', and put the code onto my movie clip, i kept getting an error for each line of code
Scene=Scene 1, Layer=Layer 1, Frame=1: Line 1: Statement must appear within on/onClipEvent handler
So i don't understand what i'm doing wrong, it seems so simple, yet it's not :sure:

[Johnny64]

Don't put it in your MovieClip
Just put it on the same time line as you movieclip.

[valpez1]

Wow...why didn't i think of that; so logical and simple. Thanks so much everyone who helped me! i could never live/fix my flash problems without ya'll.:D

[Seticus]

ur welcome