I have updated my full screen image class.
you can find it here
http://gfxcomplex.com/labs/full_screen_image.zip
This class uses bitmap smoothing for upscaling to help address image artifacts.
I have included a FLA and a swf for demoing. There is also a CSS file for the html that addressees the Padding and Margin default problems.
Usage:
import com.gfxcomplex.display.FullScreenImage;
import com.gfxcomplex.display.events.*;
var image:FullScreenImage = new FullScreenImage(new URLRequest("http://gfxcomplex.com/images/Damn_utensils_by_darkmotiondotcom.jpg"));
addChildAt(image, 0);
image.addEventListener(LoadingEvent.PROGRESS, onProgress);
image.addEventListener(LoadedEvent.COMPLETE, onComplete);
function onProgress(e:LoadingEvent):void{
trace(e.imageData.bytesLoaded, e.imageData.bytesTotal);
}
function onComplete(e:LoadedEvent):void{
trace(e.loaded);
}
here is the main class. Note there are two custom events that are needed if you make it from source, They are listed below.
FullScreenImage Class
/*////////////////////////////////////////////////////
//////////////////////////////////////////////////////
////
//// Full Browser background image
////
//// by Josh Chernoff ( GFX Complex )
//// Copy right ~ josh chernoff ~ 2007
//// All rights reseverd
////
////
//// May be redistobuted under The
//// GNU General Public License (GPL) Agreement
////
//////////////////////////////////////////////////////
*/////////////////////////////////////////////////////
/** gfxcomplex.com display package */
package com.gfxcomplex.display{
import com.gfxcomplex.display.events.*;
import caurina.transitions.Tweener;
import flash.display.Sprite;
import flash.system.LoaderContext;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.display.Bitmap;
import flash.display.Loader;
import flash.events.Event;
import flash.events.ProgressEvent;
import flash.net.URLRequest;
/**
* Loads a ("jpg or png") from a URLRequest.
* This class requires the "caurina.transitions.Tweener" class which can be found at <a href='http://code.google.com/p/tweener/'> http://code.google.com/p/tweener/ </a>
*
* @usage
* <pre>
* var backgoundImage:FullScreenImage = new FullScreenImage(url:URLRequest);
* addChild(backgoundImage);
* </pre>
*
* @version 0.2
* @author Josh Chernoff
* @author http://www.gfxcomplex.com
*/
public class FullScreenImage extends Sprite{
private var _bytesLoaded:Number;
private var _bytesTotal:Number;
private var _imageHolder:Sprite;
private var _bitmap:Bitmap;
private var _loader:Loader;
public function get bytesTotal():Number{
return _bytesTotal;
}
public function get bytesLoaded():Number{
return _bytesLoaded;
}
public function remove(){
stage.removeEventListener(Event.RESIZE, stageResized);
}
public function FullScreenImage(url:URLRequest) {
_imageHolder = new Sprite();
addChild(_imageHolder);
var loaderContext:LoaderContext = new LoaderContext(true);
_loader = new Loader();
_loader.contentLoaderInfo.addEventListener(Event.C OMPLETE, completeHandler);
_loader.contentLoaderInfo.addEventListener(Progres sEvent.PROGRESS, progressHandler);
_loader.load(url,loaderContext);
}
private function completeHandler(event:Event):void {
var sW:Number = stage.stageWidth;
var sH:Number = stage.stageHeight;
_bitmap = Bitmap(event.target.loader.content);
_bitmap.y -= _bitmap.height;
_bitmap.smoothing = true;
addChild(_imageHolder);
_imageHolder.addChild(_bitmap);
_imageHolder.width = sW;
_imageHolder.scaleY = _imageHolder.scaleX;
if (_imageHolder.height < sH) {
_imageHolder.height = sH;
_imageHolder.scaleX = _imageHolder.scaleY;
}
_imageHolder.y = sH ;
_imageHolder.alpha = 0;
Tweener.addTween(_imageHolder, {alpha:1, time:2, transition:"linear"});
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
stage.addEventListener(Event.RESIZE, stageResized);
dispatchEvent(new LoadedEvent(LoadedEvent.COMPLETE, true));
}
private function progressHandler(event:ProgressEvent):void {
var imageData:Object = new Object();
imageData.bytesLoaded = event.bytesLoaded;
imageData.bytesTotal = event.bytesTotal;
dispatchEvent(new LoadingEvent(LoadingEvent.PROGRESS, imageData));
}
private function stageResized(event:Event):void {
var sH:Number = stage.stageHeight;
_imageHolder.width = stage.stageWidth;
_imageHolder.scaleY = _imageHolder.scaleX;
if (_imageHolder.height < sH) {
_imageHolder.height = sH;
_imageHolder.scaleX = _imageHolder.scaleY;
}
_imageHolder.y = sH;
}
}
}
LoadedEvent Class:
package com.gfxcomplex.display.events{
import flash.events.Event;
public class LoadedEvent extends Event{
public static const COMPLETE:String = "loaded";
public var loaded:Boolean;
public function LoadedEvent ( type:String,
_loaded:Boolean,
bubbles:Boolean = false,
cancelable:Boolean = false) {
super(type, bubbles, cancelable);
loaded = _loaded;
}
public override function clone():Event{
return new LoadedEvent(type, loaded, bubbles, cancelable);
}
public override function toString():String{
return formatToString("LoadedEvent", "type", "loaded", "bubbles", "cancelable");
}
}
}
LoadingEvent Class:
package com.gfxcomplex.display.events{
import flash.events.Event;
public class LoadingEvent extends Event{
public static const PROGRESS:String = "loading";
public var imageData:Object;
public function LoadingEvent ( type:String,
_imageData:Object,
bubbles:Boolean = false,
cancelable:Boolean = false) {
super(type, bubbles, cancelable);
imageData = _imageData;
}
public override function clone():Event{
return new LoadingEvent(type, imageData, bubbles, cancelable);
}
public override function toString():String{
return formatToString("LoadingEvent", "type", "imageData", "bubbles", "cancelable");
}
}
}